Contenido

# función ERROR.TYPE

Devuelve un número que representa un tipo específico de error o el valor de error #N/D si no hay error.

Esta función está disponible desde la versión 5.0 de LibreOffice.

### Sintaxis

TIPO.DE.ERROR(Valor_error)

Valor_error – argumento requerido. El valor del error o una referencia a una celda cuyo valor se necesita procesar.

Valor del error | Devuelve
--- | ---
#¡NULO! (Err:521) | 1
#¡DIV/0! (Err:532) | 2
#¡VALOR! (Err:519) | 3
#¡REF! (Err:524) | 4
#¿NOMBRE? (Err:525) | 5
#¡NUM! (Err:503) | 6
#N/D (Err:32767) | 7
Cualquier otro | #N/D

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

### Ejemplos

#### Uso simple

=TIPO.DE.ERROR(#N/D)

Devuelve 7, porque 7 es el número de índice de valor del error #N/D.

=TIPO.DE.ERROR(A3)

Si A3 contiene una expresión equivalente a la división por cero, la función devuelve 2, porque 2 es el número del índice del valor del error #¡DIV/0!

#### Caminos más avanzados

Si en una división A1 por A2, A2 puede ser cero, se puede manejar la situación como sigue:

=SI(ESERROR(A1/A2);SI(ERROR.TYPE(A1/A2)=2;"el denominador no puede ser igual que cero");A1/A2)

La función ESERROR devuelve Verdadero o Falso en función de la existencia o no de un error. Si el error ocurre, la función SI responde al segundo argumento; si no hay error, devuelve el resultado de la división. El segundo argumento comprueba el número índice que representa un tipo de error específico y si es igual a 2 devuelve el texto «El denominador no puede ser cero» o 0 en cualquier otro caso. Así, el texto en claro muestra la división por cero, el resultado de la división se muestra cuando la división es correcta o si hay, por ejemplo, un error de otro tipo, devuelve 0.

Si se usa la función TIPO.DE.ERROR como condición de la función SI y el TIPO.DE.ERROR devuelve #N/D, la función SI devuelve #N/D también. Se debe utilizar ESERROR para evitarlo, como se muestra en el ejemplo anterior.

Temas relacionados

ERROR.TYPE wiki page.

ESERROR, NOD, SI

Códigos de error